1/*
2            Copyright Oliver Kowalke 2009.
3   Distributed under the Boost Software License, Version 1.0.
4      (See accompanying file LICENSE_1_0.txt or copy at
5          http://www.boost.org/LICENSE_1_0.txt)
6*/
7
8/*******************************************************
9 *                                                     *
10 *  -------------------------------------------------  *
11 *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
12 *  -------------------------------------------------  *
13 *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
14 *  -------------------------------------------------  *
15 *  | s16 | s17 | s18 | s19 | s20 | s21 | s22 | s23 |  *
16 *  -------------------------------------------------  *
17 *  -------------------------------------------------  *
18 *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
19 *  -------------------------------------------------  *
20 *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
21 *  -------------------------------------------------  *
22 *  | s24 | s25 | s26 | s27 | s28 | s29 | s30 | s31 |  *
23 *  -------------------------------------------------  *
24 *  -------------------------------------------------  *
25 *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
26 *  -------------------------------------------------  *
27 *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
28 *  -------------------------------------------------  *
29 *  | sjlj|hiddn|  v1 |  v2 |  v3 |  v4 |  v5 |  v6 |  *
30 *  -------------------------------------------------  *
31 *  -------------------------------------------------  *
32 *  |  24 |  25 |  26 |  27 |  28 |  29 |  30 |  31 |  *
33 *  -------------------------------------------------  *
34 *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
35 *  -------------------------------------------------  *
36 *  |  v7 |  v8 |  lr |  pc | FCTX| DATA|           |  *
37 *  -------------------------------------------------  *
38 *                                                     *
39 *******************************************************/
40
41.text
42.globl _jump_fcontext
43.align 2
44_jump_fcontext:
45    @ save LR as PC
46    push {lr}
47    @ save hidden,V1-V8,LR
48    push {a1,v1-v8,lr}
49
50    @ locate TLS to save/restore SjLj handler
51    mrc  p15, 0, v2, c13, c0, #3
52    bic  v2, v2, #3
53
54    @ load TLS[__PTK_LIBC_DYLD_Unwind_SjLj_Key]
55    ldr  v1, [v2, #8]
56    @ save SjLj handler
57    push  {v1}
58
59    @ prepare stack for FPU
60    sub  sp, sp, #64
61#if (defined(__VFP_FP__) && !defined(__SOFTFP__))
62    @ save S16-S31
63    vstmia sp, {d8-d15}
64#endif
65
66    @ store RSP (pointing to context-data) in A1
67    mov  a1, sp
68
69    @ restore RSP (pointing to context-data) from A2
70    mov  sp, a2
71
72#if (defined(__VFP_FP__) && !defined(__SOFTFP__))
73    @ restore S16-S31
74    vldmia  sp, {d8-d15}
75#endif
76    @ prepare stack for FPU
77    add  sp, sp, #64
78
79    @ r#estore SjLj handler
80    pop  {v1}
81    @ store SjLj handler in TLS
82    str  v1, [v2, #8]
83
84    @ restore hidden,V1-V8,LR
85    pop {a4,v1-v8,lr}
86
87    @ return transfer_t from jump
88    str  a1, [a4, #0]
89    str  a3, [a4, #4]
90    @ pass transfer_t as first arg in context function
91    @ A1 == FCTX, A2 == DATA
92    mov  a2, a3
93
94    @ restore PC
95    pop {pc}
96