xref: /curl/CMake/FindLibssh.cmake (revision 7c0b6eb3) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the libssh library
25#
26# Input variables:
27#
28# LIBSSH_INCLUDE_DIR   The libssh include directory
29# LIBSSH_LIBRARY       Path to libssh library
30#
31# Result variables:
32#
33# LIBSSH_FOUND         System has libssh
34# LIBSSH_INCLUDE_DIRS  The libssh include directories
35# LIBSSH_LIBRARIES     The libssh library names
36# LIBSSH_LIBRARY_DIRS  The libssh library directories
37# LIBSSH_CFLAGS        Required compiler flags
38# LIBSSH_VERSION       Version of libssh
39
40if(CURL_USE_PKGCONFIG AND
41   NOT DEFINED LIBSSH_INCLUDE_DIR AND
42   NOT DEFINED LIBSSH_LIBRARY)
43  find_package(PkgConfig QUIET)
44  pkg_check_modules(LIBSSH "libssh")
45endif()
46
47if(LIBSSH_FOUND)
48  string(REPLACE ";" " " LIBSSH_CFLAGS "${LIBSSH_CFLAGS}")
49  message(STATUS "Found Libssh (via pkg-config): ${LIBSSH_INCLUDE_DIRS} (found version \"${LIBSSH_VERSION}\")")
50else()
51  find_path(LIBSSH_INCLUDE_DIR NAMES "libssh/libssh.h")
52  find_library(LIBSSH_LIBRARY NAMES "ssh" "libssh")
53
54  if(LIBSSH_INCLUDE_DIR AND EXISTS "${LIBSSH_INCLUDE_DIR}/libssh/libssh_version.h")
55    set(_version_regex1 "#[\t ]*define[\t ]+LIBSSH_VERSION_MAJOR[\t ]+([0-9]+).*")
56    set(_version_regex2 "#[\t ]*define[\t ]+LIBSSH_VERSION_MINOR[\t ]+([0-9]+).*")
57    set(_version_regex3 "#[\t ]*define[\t ]+LIBSSH_VERSION_MICRO[\t ]+([0-9]+).*")
58    file(STRINGS "${LIBSSH_INCLUDE_DIR}/libssh/libssh_version.h" _version_str1 REGEX "${_version_regex1}")
59    file(STRINGS "${LIBSSH_INCLUDE_DIR}/libssh/libssh_version.h" _version_str2 REGEX "${_version_regex2}")
60    file(STRINGS "${LIBSSH_INCLUDE_DIR}/libssh/libssh_version.h" _version_str3 REGEX "${_version_regex3}")
61    string(REGEX REPLACE "${_version_regex1}" "\\1" _version_str1 "${_version_str1}")
62    string(REGEX REPLACE "${_version_regex2}" "\\1" _version_str2 "${_version_str2}")
63    string(REGEX REPLACE "${_version_regex3}" "\\1" _version_str3 "${_version_str3}")
64    set(LIBSSH_VERSION "${_version_str1}.${_version_str2}.${_version_str3}")
65    unset(_version_regex1)
66    unset(_version_regex2)
67    unset(_version_regex3)
68    unset(_version_str1)
69    unset(_version_str2)
70    unset(_version_str3)
71  endif()
72
73  include(FindPackageHandleStandardArgs)
74  find_package_handle_standard_args(Libssh
75    REQUIRED_VARS
76      LIBSSH_INCLUDE_DIR
77      LIBSSH_LIBRARY
78    VERSION_VAR
79      LIBSSH_VERSION
80  )
81
82  if(LIBSSH_FOUND)
83    set(LIBSSH_INCLUDE_DIRS ${LIBSSH_INCLUDE_DIR})
84    set(LIBSSH_LIBRARIES    ${LIBSSH_LIBRARY})
85  endif()
86
87  mark_as_advanced(LIBSSH_INCLUDE_DIR LIBSSH_LIBRARY)
88endif()
89
90if(LIBSSH_FOUND AND WIN32)
91  list(APPEND LIBSSH_LIBRARIES "iphlpapi")  # for if_nametoindex
92endif()
93