xref: /PHP-8.2/ext/mysqlnd/config9.m4 (revision 4984bd10) 
1PHP_ARG_ENABLE([mysqlnd],
2  [whether to enable mysqlnd],
3  [AS_HELP_STRING([--enable-mysqlnd],
4    [Enable mysqlnd explicitly, will be done implicitly when required by other
5    extensions])],
6  [no],
7  [yes])
8
9PHP_ARG_ENABLE([mysqlnd_compression_support],
10  [whether to disable compressed protocol support in mysqlnd],
11  [AS_HELP_STRING([--disable-mysqlnd-compression-support],
12    [Disable support for the MySQL compressed protocol in mysqlnd])],
13  [yes],
14  [no])
15
16dnl If some extension uses mysqlnd it will get compiled in PHP core
17if test "$PHP_MYSQLND" != "no" || test "$PHP_MYSQLND_ENABLED" = "yes"; then
18  mysqlnd_ps_sources="mysqlnd_ps.c mysqlnd_ps_codec.c"
19  mysqlnd_base_sources="mysqlnd_connection.c mysqlnd_alloc.c mysqlnd_charset.c mysqlnd_wireprotocol.c \
20                   mysqlnd_loaddata.c mysqlnd_reverse_api.c mysqlnd_vio.c mysqlnd_protocol_frame_codec.c \
21                   mysqlnd_statistics.c mysqlnd_driver.c mysqlnd_ext_plugin.c mysqlnd_auth.c \
22				   mysqlnd_result.c mysqlnd_result_meta.c mysqlnd_debug.c mysqlnd_commands.c \
23				   mysqlnd_block_alloc.c mysqlnd_read_buffer.c mysqlnd_plugin.c php_mysqlnd.c"
24
25
26  if test "$PHP_MYSQLND_COMPRESSION_SUPPORT" != "no"; then
27    PKG_CHECK_MODULES([ZLIB], [zlib])
28    PHP_EVAL_LIBLINE($ZLIB_LIBS, MYSQLND_SHARED_LIBADD)
29    PHP_EVAL_INCLINE($ZLIB_CFLAGS)
30    AC_DEFINE([MYSQLND_COMPRESSION_ENABLED], 1, [Enable compressed protocol support])
31  fi
32
33  AC_DEFINE([MYSQLND_SSL_SUPPORTED], 1, [Enable core mysqlnd SSL code])
34
35  test -z "$PHP_OPENSSL" && PHP_OPENSSL=no
36
37  if test "$PHP_OPENSSL" != "no" || test "$PHP_OPENSSL_DIR" != "no"; then
38    PHP_SETUP_OPENSSL(MYSQLND_SHARED_LIBADD, [AC_DEFINE(MYSQLND_HAVE_SSL,1,[Enable mysqlnd code that uses OpenSSL directly])])
39  fi
40
41  mysqlnd_sources="$mysqlnd_base_sources $mysqlnd_ps_sources"
42  PHP_NEW_EXTENSION(mysqlnd, $mysqlnd_sources, $ext_shared,, -DZEND_ENABLE_STATIC_TSRMLS_CACHE=1)
43  PHP_ADD_BUILD_DIR([ext/mysqlnd], 1)
44  PHP_INSTALL_HEADERS([ext/mysqlnd/])
45fi
46
47if test "$PHP_MYSQLND" != "no" || test "$PHP_MYSQLND_ENABLED" = "yes" || test "$PHP_MYSQLI" != "no"; then
48  PHP_ADD_BUILD_DIR([ext/mysqlnd], 1)
49fi
50