xref: /curl/CMake/FindNGHTTP3.cmake (revision f66af623) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the nghttp3 library
25#
26# Input variables:
27#
28# - `NGHTTP3_INCLUDE_DIR`:   The nghttp3 include directory.
29# - `NGHTTP3_LIBRARY`:       Path to `nghttp3` library.
30#
31# Result variables:
32#
33# - `NGHTTP3_FOUND`:         System has nghttp3.
34# - `NGHTTP3_INCLUDE_DIRS`:  The nghttp3 include directories.
35# - `NGHTTP3_LIBRARIES`:     The nghttp3 library names.
36# - `NGHTTP3_VERSION`:       Version of nghttp3.
37
38if(CURL_USE_PKGCONFIG)
39  find_package(PkgConfig QUIET)
40  pkg_check_modules(PC_NGHTTP3 "libnghttp3")
41endif()
42
43find_path(NGHTTP3_INCLUDE_DIR NAMES "nghttp3/nghttp3.h"
44  HINTS
45    ${PC_NGHTTP3_INCLUDEDIR}
46    ${PC_NGHTTP3_INCLUDE_DIRS}
47)
48
49find_library(NGHTTP3_LIBRARY NAMES "nghttp3"
50  HINTS
51    ${PC_NGHTTP3_LIBDIR}
52    ${PC_NGHTTP3_LIBRARY_DIRS}
53)
54
55if(PC_NGHTTP3_VERSION)
56  set(NGHTTP3_VERSION ${PC_NGHTTP3_VERSION})
57elseif(NGHTTP3_INCLUDE_DIR AND EXISTS "${NGHTTP3_INCLUDE_DIR}/nghttp3/version.h")
58  set(_version_regex "#[\t ]*define[\t ]+NGHTTP3_VERSION[\t ]+\"([^\"]*)\"")
59  file(STRINGS "${NGHTTP3_INCLUDE_DIR}/nghttp3/version.h" _version_str REGEX "${_version_regex}")
60  string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
61  set(NGHTTP3_VERSION "${_version_str}")
62  unset(_version_regex)
63  unset(_version_str)
64endif()
65
66include(FindPackageHandleStandardArgs)
67find_package_handle_standard_args(NGHTTP3
68  REQUIRED_VARS
69    NGHTTP3_INCLUDE_DIR
70    NGHTTP3_LIBRARY
71  VERSION_VAR
72    NGHTTP3_VERSION
73)
74
75if(NGHTTP3_FOUND)
76  set(NGHTTP3_INCLUDE_DIRS ${NGHTTP3_INCLUDE_DIR})
77  set(NGHTTP3_LIBRARIES    ${NGHTTP3_LIBRARY})
78endif()
79
80mark_as_advanced(NGHTTP3_INCLUDE_DIR NGHTTP3_LIBRARY)
81