xref: /curl/CMake/FindLibssh2.cmake (revision f66af623) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the libssh2 library
25#
26# Input variables:
27#
28# - `LIBSSH2_INCLUDE_DIR`:   The libssh2 include directory.
29# - `LIBSSH2_LIBRARY`:       Path to `libssh2` library.
30#
31# Result variables:
32#
33# - `LIBSSH2_FOUND`:         System has libssh2.
34# - `LIBSSH2_INCLUDE_DIRS`:  The libssh2 include directories.
35# - `LIBSSH2_LIBRARIES`:     The libssh2 library names.
36# - `LIBSSH2_VERSION`:       Version of libssh2.
37
38if(CURL_USE_PKGCONFIG)
39  find_package(PkgConfig QUIET)
40  pkg_check_modules(PC_LIBSSH2 "libssh2")
41endif()
42
43find_path(LIBSSH2_INCLUDE_DIR NAMES "libssh2.h"
44  HINTS
45    ${PC_LIBSSH2_INCLUDEDIR}
46    ${PC_LIBSSH2_INCLUDE_DIRS}
47)
48
49find_library(LIBSSH2_LIBRARY NAMES "ssh2" "libssh2"
50  HINTS
51    ${PC_LIBSSH2_LIBDIR}
52    ${PC_LIBSSH2_LIBRARY_DIRS}
53)
54
55if(PC_LIBSSH2_VERSION)
56  set(LIBSSH2_VERSION ${PC_LIBSSH2_VERSION})
57elseif(LIBSSH2_INCLUDE_DIR AND EXISTS "${LIBSSH2_INCLUDE_DIR}/libssh2.h")
58  set(_version_regex "#[\t ]*define[\t ]+LIBSSH2_VERSION[\t ]+\"([^\"]*)\"")
59  file(STRINGS "${LIBSSH2_INCLUDE_DIR}/libssh2.h" _version_str REGEX "${_version_regex}")
60  string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
61  set(LIBSSH2_VERSION "${_version_str}")
62  unset(_version_regex)
63  unset(_version_str)
64endif()
65
66include(FindPackageHandleStandardArgs)
67find_package_handle_standard_args(Libssh2
68  REQUIRED_VARS
69    LIBSSH2_INCLUDE_DIR
70    LIBSSH2_LIBRARY
71  VERSION_VAR
72    LIBSSH2_VERSION
73)
74
75if(LIBSSH2_FOUND)
76  set(LIBSSH2_INCLUDE_DIRS ${LIBSSH2_INCLUDE_DIR})
77  set(LIBSSH2_LIBRARIES    ${LIBSSH2_LIBRARY})
78endif()
79
80mark_as_advanced(LIBSSH2_INCLUDE_DIR LIBSSH2_LIBRARY)
81