xref: /curl/CMake/CurlSymbolHiding.cmake (revision 9acecc92) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24option(CURL_HIDDEN_SYMBOLS "Hide libcurl internal symbols (=hide all symbols that are not officially external)" ON)
25mark_as_advanced(CURL_HIDDEN_SYMBOLS)
26
27if(WIN32 AND (ENABLE_DEBUG OR ENABLE_CURLDEBUG))
28  # We need to export internal debug functions,
29  # e.g. curl_easy_perform_ev() or curl_dbg_*(),
30  # so disable symbol hiding for debug builds and for memory tracking.
31  set(CURL_HIDDEN_SYMBOLS OFF)
32endif()
33
34set(CURL_HIDES_PRIVATE_SYMBOLS FALSE)
35unset(CURL_EXTERN_SYMBOL)
36unset(CURL_CFLAG_SYMBOLS_HIDE)
37
38if(CURL_HIDDEN_SYMBOLS)
39  if(CMAKE_C_COMPILER_ID MATCHES "Clang" AND NOT MSVC)
40    set(CURL_HIDES_PRIVATE_SYMBOLS TRUE)
41    set(CURL_EXTERN_SYMBOL "__attribute__((__visibility__(\"default\")))")
42    set(CURL_CFLAG_SYMBOLS_HIDE "-fvisibility=hidden")
43  elseif(CMAKE_COMPILER_IS_GNUCC)
44    if(NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 3.4)
45      # Note: This is considered buggy prior to 4.0 but the autotools do not care, so let us ignore that fact
46      set(CURL_HIDES_PRIVATE_SYMBOLS TRUE)
47      set(CURL_EXTERN_SYMBOL "__attribute__((__visibility__(\"default\")))")
48      set(CURL_CFLAG_SYMBOLS_HIDE "-fvisibility=hidden")
49    endif()
50  elseif(CMAKE_C_COMPILER_ID MATCHES "SunPro" AND NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 8.0)
51    set(CURL_HIDES_PRIVATE_SYMBOLS TRUE)
52    set(CURL_EXTERN_SYMBOL "__global")
53    set(CURL_CFLAG_SYMBOLS_HIDE "-xldscope=hidden")
54  elseif(CMAKE_C_COMPILER_ID MATCHES "Intel" AND NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 9.0)  # Requires 9.1.045
55    set(CURL_HIDES_PRIVATE_SYMBOLS TRUE)
56    set(CURL_EXTERN_SYMBOL "__attribute__((__visibility__(\"default\")))")
57    set(CURL_CFLAG_SYMBOLS_HIDE "-fvisibility=hidden")
58  elseif(MSVC)
59    set(CURL_HIDES_PRIVATE_SYMBOLS TRUE)
60  endif()
61else()
62  if(MSVC)
63    # Note: This option is prone to export non-curl extra symbols.
64    set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
65  endif()
66endif()
67