xref: /PHP-7.3/ext/oci8/config.m4 (revision eceb3407) 
1if test -z "$SED"; then
2  PHP_OCI8_SED="sed";
3else
4  PHP_OCI8_SED="$SED";
5fi
6
7PHP_OCI8_TAIL1=`echo a | tail -n1 2>/dev/null`
8if test "$PHP_OCI8_TAIL1" = "a"; then
9    PHP_OCI8_TAIL1="tail -n1"
10else
11    PHP_OCI8_TAIL1="tail -1"
12fi
13
14AC_DEFUN([AC_OCI8_CHECK_LIB_DIR],[
15  AC_MSG_CHECKING([ORACLE_HOME library validity])
16  if test ! -d "$OCI8_DIR"; then
17    AC_MSG_ERROR([${OCI8_DIR} is not a directory])
18  fi
19  if test -d "$OCI8_DIR/lib" && test ! -d "$OCI8_DIR/lib32"; then
20    OCI8_LIB_DIR=lib
21  elif test ! -d "$OCI8_DIR/lib" && test -d "$OCI8_DIR/lib32"; then
22    OCI8_LIB_DIR=lib32
23  elif test -d "$OCI8_DIR/lib" && test -d "$OCI8_DIR/lib32"; then
24    OCI8_LIB_DIR=$PHP_OCI8_OH_LIBDIR
25  else
26    dnl This isn't an ORACLE_HOME.  Try heuristic examination of the dir to help the user
27    if test -f "$OCI8_DIR/libociei.$SHLIB_SUFFIX_NAME"; then
28      AC_MSG_ERROR([Expected an ORACLE_HOME top level directory but ${OCI8_DIR} appears to be an Instant Client directory. Try --with-oci8=instantclient,${OCI8_DIR}])
29    else
30      AC_MSG_ERROR([Oracle library directory not found in ${OCI8_DIR}])
31    fi
32  fi
33  AC_MSG_RESULT($OCI8_LIB_DIR)
34])
35
36AC_DEFUN([AC_OCI8IC_VERSION],[
37  AC_MSG_CHECKING([Oracle Instant Client library version compatibility])
38  OCI8_LCS_BASE=$PHP_OCI8_INSTANT_CLIENT/libclntsh.$SHLIB_SUFFIX_NAME
39  OCI8_LCS=`ls $OCI8_LCS_BASE.*.1 2> /dev/null | $PHP_OCI8_TAIL1`  # Oracle 10g, 11g etc
40  OCI8_NNZ=`ls $PHP_OCI8_INSTANT_CLIENT/libnnz*.$SHLIB_SUFFIX_NAME 2> /dev/null | $PHP_OCI8_TAIL1`
41  if test -f "$OCI8_NNZ" && test -f "$OCI8_LCS"; then
42    if test ! -f "$OCI8_LCS_BASE"; then
43      AC_MSG_ERROR([Link from $OCI8_LCS_BASE to $OCI8_LCS_BASE.*.1 not found])
44    fi
45    OCI8_ORACLE_VERSION=`echo $OCI8_LCS | $PHP_OCI8_SED -e 's/.*\.\(.*\)\.1$/\1.1/'`
46  else
47    AC_MSG_ERROR([Oracle Instant Client libraries libnnz.$SHLIB_SUFFIX_NAME and libclntsh.$SHLIB_SUFFIX_NAME not found])
48  fi
49  AC_MSG_RESULT([$OCI8_ORACLE_VERSION])
50])
51
52AC_DEFUN([AC_OCI8_ORACLE_VERSION],[
53  AC_MSG_CHECKING([Oracle library version compatibility])
54  OCI8_LCS_BASE=$OCI8_DIR/$OCI8_LIB_DIR/libclntsh.$SHLIB_SUFFIX_NAME
55  OCI8_LCS=`ls $OCI8_LCS_BASE.*.1 2> /dev/null | $PHP_OCI8_TAIL1`  # Oracle 10g, 11g etc
56  if test -s "$OCI8_DIR/orainst/unix.rgs"; then
57    OCI8_ORACLE_VERSION=`grep '"ocommon"' $OCI8_DIR/orainst/unix.rgs | $PHP_OCI8_SED 's/[ ][ ]*/:/g' | cut -d: -f 6 | cut -c 2-4`
58    test -z "$OCI8_ORACLE_VERSION" && OCI8_ORACLE_VERSION=7.3
59  elif test -f "$OCI8_LCS"; then
60    dnl Oracle 10g, 11g etc.  The x.2 version libraries are named x.1 for drop in compatibility
61    OCI8_ORACLE_VERSION=`echo $OCI8_LCS | $PHP_OCI8_SED -e 's/.*\.\(.*\)\.1$/\1.1/'`
62  elif test -f $OCI8_LCS_BASE.9.0; then
63    dnl There is no case for Oracle 9.2. Oracle 9.2 libraries have a 9.0 suffix for drop-in compatibility with Oracle 9.0
64    OCI8_ORACLE_VERSION=9.0
65  elif test -f $OCI8_LCS_BASE.8.0; then
66    OCI8_ORACLE_VERSION=8.1
67  elif test -f $OCI8_LCS_BASE.1.0; then
68    OCI8_ORACLE_VERSION=8.0
69  elif test -f $OCI8_DIR/$OCI8_LIB_DIR/libclntsh.a; then
70    if test -f $OCI8_DIR/$OCI8_LIB_DIR/libcore4.a; then
71      OCI8_ORACLE_VERSION=8.0
72    else
73      OCI8_ORACLE_VERSION=8.1
74    fi
75  else
76    AC_MSG_ERROR(Oracle libclntsh.$SHLIB_SUFFIX_NAME client library not found)
77  fi
78  AC_MSG_RESULT($OCI8_ORACLE_VERSION)
79])
80
81dnl
82dnl OCI8_INIT_DTRACE(providerdesc, header-file, sources)
83dnl This mimics PHP_INIT_DTRACE from PHP 5.4's acinclude.m4. It is
84dnl necessarily different from PHP_INIT_DTRACE which doesn't currently
85dnl support DTrace for extensions.  Creating OCI8_INIT_DTRACE
86dnl independently instead of using a refactored PHP_INIT_DTRACE allows
87dnl OCI8 to be DTraced on versions of PHP where core PHP DTrace support
88dnl isn't available.
89dnl
90AC_DEFUN([OCI8_INIT_DTRACE],[
91  ac_srcdir=[]PHP_EXT_SRCDIR([oci8])/
92  ac_bdir=[]PHP_EXT_BUILDDIR([oci8])/
93
94dnl providerdesc
95  ac_provsrc=$1
96
97dnl header-file
98  ac_hdrobj=$2
99
100dnl DTrace objects
101  old_IFS=[$]IFS
102  for ac_src in $3; do
103    IFS=.
104    set $ac_src
105    ac_obj=[$]1
106    IFS=$old_IFS
107
108    OCI8_DTRACE_OBJS="[$]OCI8_DTRACE_OBJS [$]ac_bdir[$]ac_obj.lo"
109  done;
110
111  for ac_lo in $OCI8_DTRACE_OBJS; do
112    dtrace_oci8_objs="[$]dtrace_oci8_objs `echo $ac_lo | $SED -e 's,\.lo$,.o,' -e 's#\(.*\)\/#\1\/.libs\/#'`"
113  done;
114
115dnl Generate Makefile.objects entry
116dnl The empty $ac_provsrc command stops an implicit circular dependency
117dnl in GNU Make which causes the .d file to be overwritten (Bug 61268)
118  cat>>Makefile.objects<<EOF
119
120PHP_EXT_SRCDIR([oci8])/$ac_provsrc:;
121
122$ac_bdir[$]ac_hdrobj: $ac_srcdir[$]ac_provsrc
123	CFLAGS="\$(CFLAGS_CLEAN)" dtrace -h -C -s $ac_srcdir[$]ac_provsrc -o \$[]@.bak && \$(SED) -e 's,PHPOCI_,DTRACE_,g' \$[]@.bak > \$[]@
124
125\$(OCI8_DTRACE_OBJS): $ac_bdir[$]ac_hdrobj
126
127EOF
128
129  case $host_alias in
130  *solaris*|*linux*)
131    dtrace_prov_name="`echo $ac_provsrc | $SED -e 's#\(.*\)\/##'`.o"
132    dtrace_lib_dir="`echo $ac_bdir[$]ac_provsrc | $SED -e 's#\(.*\)/[^/]*#\1#'`/.libs"
133    dtrace_d_obj="`echo $ac_bdir[$]ac_provsrc | $SED -e 's#\(.*\)/\([^/]*\)#\1/.libs/\2#'`.o"
134    dtrace_nolib_objs='$(OCI8_DTRACE_OBJS:.lo=.o)'
135    for ac_lo in $OCI8_DTRACE_OBJS; do
136      dtrace_oci8_lib_objs="[$]dtrace_oci8_lib_objs `echo $ac_lo | $SED -e 's,\.lo$,.o,' -e 's#\(.*\)\/#\1\/.libs\/#'`"
137    done;
138dnl Always attempt to create both PIC and non-PIC DTrace objects (Bug 63692)
139    cat>>Makefile.objects<<EOF
140$ac_bdir[$]ac_provsrc.lo: \$(OCI8_DTRACE_OBJS)
141	echo "[#] Generated by Makefile for libtool" > \$[]@
142	@test -d "$dtrace_lib_dir" || mkdir $dtrace_lib_dir
143	if CFLAGS="\$(CFLAGS_CLEAN)" dtrace -G -o $dtrace_d_obj -s $ac_srcdir[$]ac_provsrc $dtrace_oci8_lib_objs 2> /dev/null && test -f "$dtrace_d_obj"; then [\\]
144	  echo "pic_object=['].libs/$dtrace_prov_name[']" >> \$[]@ [;\\]
145	else [\\]
146	  echo "pic_object='none'" >> \$[]@ [;\\]
147	fi
148	if CFLAGS="\$(CFLAGS_CLEAN)" dtrace -G -o $ac_bdir[$]ac_provsrc.o -s $ac_srcdir[$]ac_provsrc $dtrace_nolib_objs 2> /dev/null && test -f "$ac_bdir[$]ac_provsrc.o"; then [\\]
149	  echo "non_pic_object=[']$dtrace_prov_name[']" >> \$[]@ [;\\]
150	else [\\]
151	  echo "non_pic_object='none'" >> \$[]@ [;\\]
152	fi
153
154EOF
155    ;;
156  *)
157    AC_MSG_WARN([OCI8 extension: OCI8 DTrace support is not confirmed on this platform])
158cat>>Makefile.objects<<EOF
159$ac_bdir[$]ac_provsrc.o: \$(OCI8_DTRACE_OBJS)
160	CFLAGS="\$(CFLAGS_CLEAN)" dtrace -G -o \$[]@ -s $ac_srcdir[$]ac_provsrc $dtrace_oci8_objs
161
162EOF
163    ;;
164  esac
165])
166
167
168dnl --with-oci8=shared,instantclient,/path/to/client/dir/lib
169dnl or
170dnl --with-oci8=shared,/path/to/oracle/home
171PHP_ARG_WITH(oci8, for Oracle Database OCI8 support,
172[  --with-oci8[=DIR]         Include Oracle Database OCI8 support. DIR defaults to [$]ORACLE_HOME.
173                          Use --with-oci8=instantclient,/path/to/instant/client/lib
174                          to use an Oracle Instant Client installation])
175
176if test "$PHP_OCI8" != "no"; then
177
178  if test -z "$PHP_OCI8"; then
179    dnl --with-oci8=$ORACLE_HOME where ORACLE_HOME isn't set (or is mistyped) will match this case
180    AC_MSG_ERROR([Empty parameter value passed to --with-oci8])
181  fi
182
183  dnl Check PHP version is compatible with this extension
184
185  AC_MSG_CHECKING([PHP version])
186
187  tmp_version=$PHP_VERSION
188  if test -z "$tmp_version"; then
189    if test -z "$PHP_CONFIG"; then
190      AC_MSG_ERROR([php-config not found])
191    fi
192    php_version=`$PHP_CONFIG --version 2>/dev/null|head -n 1|$PHP_OCI8_SED -e 's#\([0-9]\.[0-9]*\.[0-9]*\)\(.*\)#\1#'`
193  else
194    php_version=`echo "$tmp_version"|$PHP_OCI8_SED -e 's#\([0-9]\.[0-9]*\.[0-9]*\)\(.*\)#\1#'`
195  fi
196
197  if test -z "$php_version"; then
198    AC_MSG_ERROR([failed to detect PHP version, please report])
199  fi
200
201  ac_IFS=$IFS
202  IFS="."
203  set $php_version
204  IFS=$ac_IFS
205  oci8_php_version=`expr [$]1 \* 1000000 + [$]2 \* 1000 + [$]3`
206
207  if test "$oci8_php_version" -lt "5002000"; then
208    AC_MSG_ERROR([You need at least PHP 5.2.0 to be able to use this version of OCI8. PHP $php_version found])
209  else
210    AC_MSG_RESULT([$php_version, ok])
211  fi
212
213  dnl Check whether --enable-dtrace was set.
214  dnl To use DTrace with a PECL install, extract the OCI8 archive, phpize it, and set
215  dnl PHP_DTRACE=yes before running configure
216  AC_MSG_CHECKING([OCI8 DTrace support])
217  oci8_do_dtrace="`echo $PHP_OCI8 | cut -d, -f3`"
218  if test "$PHP_DTRACE" = "yes" -o "$oci8_do_dtrace" = "dtrace" ; then
219    AC_MSG_RESULT([yes])
220    if test "$ext_shared" = "no"; then
221      AC_MSG_ERROR([For DTrace support OCI8 must be configured as a shared extension])
222    else
223      AC_CHECK_HEADERS([sys/sdt.h], [
224	 OCI8_INIT_DTRACE([oci8_dtrace.d],[oci8_dtrace_gen.h],[oci8.c oci8_statement.c])
225
226       ], [
227	 AC_MSG_ERROR(
228	   [Cannot find sys/sdt.h which is required for DTrace support])
229       ])
230      PHP_SUBST(OCI8_DTRACE_OBJS)
231      AC_DEFINE(HAVE_OCI8_DTRACE,1,[Defined to 1 if PHP OCI8 DTrace support was enabled during configuration])
232      dnl Developer warning: hard coded extension is OK for the known supported environments
233      shared_objects_oci8="$shared_objects_oci8 PHP_EXT_BUILDDIR(oci8)/oci8_dtrace.d.lo"
234    fi
235  else
236    AC_MSG_RESULT([no])
237  fi
238
239  dnl Set some port specific directory components for use later
240
241  AC_CHECK_SIZEOF(long int, 4)
242  AC_MSG_CHECKING([checking if we're on a 64-bit platform])
243  if test "$ac_cv_sizeof_long_int" = "4"; then
244    AC_MSG_RESULT([no])
245    PHP_OCI8_OH_LIBDIR=lib32
246    PHP_OCI8_IC_LIBDIR_SUFFIX=""
247  else
248    AC_MSG_RESULT([yes])
249    PHP_OCI8_OH_LIBDIR=lib
250    PHP_OCI8_IC_LIBDIR_SUFFIX=64
251  fi
252
253  dnl Determine if the user wants to use Oracle Instant Client libraries
254
255  PHP_OCI8_INSTANT_CLIENT="no"
256
257  dnl PECL Bug 14268 (Allow "pecl install oci8" command to "autodetect"
258  dnl an Instant Client RPM install).  This also has a benefit for non
259  dnl "pecl install" builds: if the user does --with-oci8 or
260  dnl --with-oci8=shared but the ORACLE_HOME environment variable is not
261  dnl actually set, the install tries to locate the Instant Client RPM
262  if test "$PHP_OCI8" = "yes" && test -z "$ORACLE_HOME"; then
263    AC_MSG_WARN([OCI8 extension: ORACLE_HOME is not set, looking for default Oracle Instant Client instead])
264    PHP_OCI8=instantclient
265  fi
266
267  if test "`echo $PHP_OCI8`" = "instantclient"; then
268    PHP_OCI8_INSTANT_CLIENT="yes"
269  elif test "`echo $PHP_OCI8 | cut -d, -f2`" = "instantclient"; then
270    PHP_OCI8_INSTANT_CLIENT="`echo $PHP_OCI8 | cut -d, -f3`"
271    PHP_OCI8="`echo $PHP_OCI8 | cut -d, -f1,4`"
272    if test "$PHP_OCI8_INSTANT_CLIENT" = ""; then
273	PHP_OCI8_INSTANT_CLIENT="yes"
274    fi
275    if test -z "$PHP_OCI8"; then
276	PHP_OCI8=yes
277    fi
278  elif test "`echo $PHP_OCI8 | cut -d, -f1`" = "instantclient"; then
279    PHP_OCI8_INSTANT_CLIENT="`echo $PHP_OCI8 | cut -d, -f2`"
280    PHP_OCI8="`echo $PHP_OCI8 | cut -d, -f3,4`"
281    if test "$PHP_OCI8_INSTANT_CLIENT" = ""; then
282	PHP_OCI8_INSTANT_CLIENT="yes"
283    fi
284    if test -z "$PHP_OCI8"; then
285	PHP_OCI8=yes
286    fi
287  fi
288
289  if test "$PHP_OCI8_INSTANT_CLIENT" = "no"; then
290    dnl ***************************************
291    dnl Branch for using an ORACLE_HOME install
292    dnl ***************************************
293
294    AC_MSG_CHECKING([Oracle ORACLE_HOME install directory])
295
296    if test "$PHP_OCI8" = "yes"; then
297      OCI8_DIR=$ORACLE_HOME
298    else
299      OCI8_DIR=$PHP_OCI8
300    fi
301    AC_MSG_RESULT($OCI8_DIR)
302
303    AC_OCI8_CHECK_LIB_DIR($OCI8_DIR)
304
305    if test -d "$OCI8_DIR/rdbms/public"; then
306      PHP_ADD_INCLUDE($OCI8_DIR/rdbms/public)
307      OCI8_INCLUDES="$OCI8_INCLUDES -I$OCI8_DIR/rdbms/public"
308    fi
309    if test -d "$OCI8_DIR/rdbms/demo"; then
310      PHP_ADD_INCLUDE($OCI8_DIR/rdbms/demo)
311      OCI8_INCLUDES="$OCI8_INCLUDES -I$OCI8_DIR/rdbms/demo"
312    fi
313    if test -d "$OCI8_DIR/network/public"; then
314      PHP_ADD_INCLUDE($OCI8_DIR/network/public)
315      OCI8_INCLUDES="$OCI8_INCLUDES -I$OCI8_DIR/network/public"
316    fi
317    if test -d "$OCI8_DIR/plsql/public"; then
318      PHP_ADD_INCLUDE($OCI8_DIR/plsql/public)
319      OCI8_INCLUDES="$OCI8_INCLUDES -I$OCI8_DIR/plsql/public"
320    fi
321
322    if test -f "$OCI8_DIR/$OCI8_LIB_DIR/sysliblist"; then
323      PHP_EVAL_LIBLINE(`cat $OCI8_DIR/$OCI8_LIB_DIR/sysliblist`, OCI8_SYSLIB)
324    elif test -f "$OCI8_DIR/rdbms/$OCI8_LIB_DIR/sysliblist"; then
325      PHP_EVAL_LIBLINE(`cat $OCI8_DIR/rdbms/$OCI8_LIB_DIR/sysliblist`, OCI8_SYSLIB)
326    fi
327
328    AC_OCI8_ORACLE_VERSION($OCI8_DIR)
329
330    case $OCI8_ORACLE_VERSION in
331      7.3|8.0|8.1|9.0)
332	AC_MSG_ERROR([Oracle client libraries < 10 are not supported])
333	;;
334    esac
335
336    PHP_ADD_LIBRARY(clntsh, 1, OCI8_SHARED_LIBADD)
337    PHP_ADD_LIBPATH($OCI8_DIR/$OCI8_LIB_DIR, OCI8_SHARED_LIBADD)
338    PHP_NEW_EXTENSION(oci8, oci8.c oci8_lob.c oci8_statement.c oci8_collection.c oci8_interface.c oci8_failover.c, $ext_shared)
339    AC_DEFINE(HAVE_OCI8,1,[Defined to 1 if the PHP OCI8 extension for Oracle Database is configured])
340
341    PHP_SUBST_OLD(OCI8_SHARED_LIBADD)
342    PHP_SUBST_OLD(OCI8_DIR)
343    PHP_SUBST_OLD(OCI8_ORACLE_VERSION)
344
345    dnl Fix Bug #46623
346    AC_DEFINE_UNQUOTED(PHP_OCI8_DEF_DIR, "$OCI8_DIR", [ ])
347    AC_DEFINE_UNQUOTED(PHP_OCI8_DEF_SHARED_LIBADD, "$OCI8_SHARED_LIBADD", [ ])
348
349  else
350    dnl ***************************************************
351    dnl Branch for using an Oracle Instant Client directory
352    dnl ***************************************************
353
354    AC_MSG_CHECKING([Oracle Instant Client directory])
355
356    if test "$PHP_OCI8_INSTANT_CLIENT" = "yes"; then
357      dnl Find the directory if user specified "instantclient" but did not
358      dnl give a dir. Generally the Instant Client can be anywhere so the
359      dnl user must pass in the library directory.  But on Linux we default
360      dnl to the most recent version in /usr/lib which is where the Oracle
361      dnl Instant Client RPM gets installed.
362      PHP_OCI8_INSTANT_CLIENT=`ls -d /usr/lib/oracle/*/client${PHP_OCI8_IC_LIBDIR_SUFFIX}/lib/libclntsh.* 2> /dev/null | $PHP_OCI8_TAIL1 | $PHP_OCI8_SED -e 's#/libclntsh[^/]*##'`
363      if test -z "$PHP_OCI8_INSTANT_CLIENT"; then
364	AC_MSG_ERROR([Oracle Instant Client directory /usr/lib/oracle/.../client${PHP_OCI8_IC_LIBDIR_SUFFIX}/lib libraries not found. Try --with-oci8=instantclient,DIR])
365      fi
366    fi
367    AC_MSG_RESULT($PHP_OCI8_INSTANT_CLIENT)
368
369    OCI8_DIR=$PHP_OCI8_INSTANT_CLIENT
370
371    AC_MSG_CHECKING([Oracle Instant Client SDK header directory])
372
373    dnl Header directory for Instant Client SDK RPM install
374    OCISDKRPMINC=`echo "$PHP_OCI8_INSTANT_CLIENT" | $PHP_OCI8_SED -e 's!^/usr/lib/oracle/\(.*\)/client\('${PHP_OCI8_IC_LIBDIR_SUFFIX}'\)*/lib[/]*$!/usr/include/oracle/\1/client\2!'`
375
376    dnl Header directory for Instant Client SDK zip file install
377    OCISDKZIPINC=$PHP_OCI8_INSTANT_CLIENT/sdk/include
378
379    dnl Header directory for manual installation
380    OCISDKMANINC=`echo "$PHP_OCI8_INSTANT_CLIENT" | $PHP_OCI8_SED -e 's!\(.*\)/lib[/]*$!\1/include!'`
381
382    if test -f "$OCISDKRPMINC/oci.h"; then
383      AC_MSG_RESULT($OCISDKRPMINC)
384      PHP_ADD_INCLUDE($OCISDKRPMINC)
385      OCI8INCDIR=$OCISDKRPMINC
386    elif test -f "$OCISDKZIPINC/oci.h"; then
387      AC_MSG_RESULT($OCISDKZIPINC)
388      PHP_ADD_INCLUDE($OCISDKZIPINC)
389      OCI8INCDIR=$OCISDKZIPINC
390    elif test -f "$OCISDKMANINC/oci.h"; then
391      AC_MSG_RESULT($OCISDKMANINC)
392      PHP_ADD_INCLUDE($OCISDKMANINC)
393      OCI8INCDIR=$OCISDKMANINC
394    else
395      AC_MSG_ERROR([Oracle Instant Client SDK header files not found])
396    fi
397
398    OCISYSLIBLIST=`echo "$OCI8INCDIR" | $PHP_OCI8_SED -e 's!\(.*\)/include$!\1/demo/sysliblist!'`
399    if test -f "$OCISYSLIBLIST"; then
400      PHP_EVAL_LIBLINE(`cat $OCISYSLIBLIST`, OCI8_SYSLIB)
401    fi
402
403    AC_OCI8IC_VERSION($PHP_OCI8_INSTANT_CLIENT)
404    PHP_ADD_LIBRARY(clntsh, 1, OCI8_SHARED_LIBADD)
405    PHP_ADD_LIBPATH($PHP_OCI8_INSTANT_CLIENT, OCI8_SHARED_LIBADD)
406
407    AC_DEFINE(HAVE_OCI_INSTANT_CLIENT,1,[Defined to 1 if OCI8 configuration located Oracle's Instant Client libraries])
408
409    PHP_NEW_EXTENSION(oci8, oci8.c oci8_lob.c oci8_statement.c oci8_collection.c oci8_interface.c oci8_failover.c, $ext_shared)
410    AC_DEFINE(HAVE_OCI8,1,[Defined to 1 if the PHP OCI8 extension for Oracle Database is configured])
411
412    PHP_SUBST_OLD(OCI8_SHARED_LIBADD)
413    PHP_SUBST_OLD(OCI8_DIR)
414    PHP_SUBST_OLD(OCI8_ORACLE_VERSION)
415
416  fi
417fi
418