xref: /curl/CMake/FindLibuv.cmake (revision 7c0b6eb3) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the libuv library
25#
26# Input variables:
27#
28# LIBUV_INCLUDE_DIR   The libuv include directory
29# LIBUV_LIBRARY       Path to libuv library
30#
31# Result variables:
32#
33# LIBUV_FOUND         System has libuv
34# LIBUV_INCLUDE_DIRS  The libuv include directories
35# LIBUV_LIBRARIES     The libuv library names
36# LIBUV_LIBRARY_DIRS  The libuv library directories
37# LIBUV_CFLAGS        Required compiler flags
38# LIBUV_VERSION       Version of libuv
39
40if(CURL_USE_PKGCONFIG AND
41   NOT DEFINED LIBUV_INCLUDE_DIR AND
42   NOT DEFINED LIBUV_LIBRARY)
43  find_package(PkgConfig QUIET)
44  pkg_check_modules(LIBUV "libuv")
45endif()
46
47if(LIBUV_FOUND)
48  string(REPLACE ";" " " LIBUV_CFLAGS "${LIBUV_CFLAGS}")
49  message(STATUS "Found Libuv (via pkg-config): ${LIBUV_INCLUDE_DIRS} (found version \"${LIBUV_VERSION}\")")
50else()
51  find_path(LIBUV_INCLUDE_DIR NAMES "uv.h")
52  find_library(LIBUV_LIBRARY NAMES "uv" "libuv")
53
54  if(LIBUV_INCLUDE_DIR AND EXISTS "${LIBUV_INCLUDE_DIR}/uv/version.h")
55    set(_version_regex1 "#[\t ]*define[\t ]+UV_VERSION_MAJOR[\t ]+([0-9]+).*")
56    set(_version_regex2 "#[\t ]*define[\t ]+UV_VERSION_MINOR[\t ]+([0-9]+).*")
57    set(_version_regex3 "#[\t ]*define[\t ]+UV_VERSION_PATCH[\t ]+([0-9]+).*")
58    file(STRINGS "${LIBUV_INCLUDE_DIR}/uv/version.h" _version_str1 REGEX "${_version_regex1}")
59    file(STRINGS "${LIBUV_INCLUDE_DIR}/uv/version.h" _version_str2 REGEX "${_version_regex2}")
60    file(STRINGS "${LIBUV_INCLUDE_DIR}/uv/version.h" _version_str3 REGEX "${_version_regex3}")
61    string(REGEX REPLACE "${_version_regex1}" "\\1" _version_str1 "${_version_str1}")
62    string(REGEX REPLACE "${_version_regex2}" "\\1" _version_str2 "${_version_str2}")
63    string(REGEX REPLACE "${_version_regex3}" "\\1" _version_str3 "${_version_str3}")
64    set(LIBUV_VERSION "${_version_str1}.${_version_str2}.${_version_str3}")
65    unset(_version_regex1)
66    unset(_version_regex2)
67    unset(_version_regex3)
68    unset(_version_str1)
69    unset(_version_str2)
70    unset(_version_str3)
71  endif()
72
73  include(FindPackageHandleStandardArgs)
74  find_package_handle_standard_args(Libuv
75    REQUIRED_VARS
76      LIBUV_INCLUDE_DIR
77      LIBUV_LIBRARY
78    VERSION_VAR
79      LIBUV_VERSION
80  )
81
82  if(LIBUV_FOUND)
83    set(LIBUV_INCLUDE_DIRS ${LIBUV_INCLUDE_DIR})
84    set(LIBUV_LIBRARIES    ${LIBUV_LIBRARY})
85  endif()
86
87  mark_as_advanced(LIBUV_INCLUDE_DIR LIBUV_LIBRARY)
88endif()
89