xref: /curl/CMake/FindRustls.cmake (revision f66af623) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the Rustls library
25#
26# Input variables:
27#
28# - `RUSTLS_INCLUDE_DIR`:   The Rustls include directory.
29# - `RUSTLS_LIBRARY`:       Path to `rustls` library.
30#
31# Result variables:
32#
33# - `RUSTLS_FOUND`:         System has Rustls.
34# - `RUSTLS_INCLUDE_DIRS`:  The Rustls include directories.
35# - `RUSTLS_LIBRARIES`:     The Rustls library names.
36# - `RUSTLS_LIBRARY_DIRS`:  The Rustls library directories.
37# - `RUSTLS_CFLAGS`:        Required compiler flags.
38# - `RUSTLS_VERSION`:       Version of Rustls.
39
40if(CURL_USE_PKGCONFIG AND
41   NOT DEFINED RUSTLS_INCLUDE_DIR AND
42   NOT DEFINED RUSTLS_LIBRARY)
43  find_package(PkgConfig QUIET)
44  pkg_check_modules(RUSTLS "rustls")
45endif()
46
47if(RUSTLS_FOUND)
48  string(REPLACE ";" " " RUSTLS_CFLAGS "${RUSTLS_CFLAGS}")
49  message(STATUS "Found Rustls (via pkg-config): ${RUSTLS_INCLUDE_DIRS} (found version \"${RUSTLS_VERSION}\")")
50else()
51  find_path(RUSTLS_INCLUDE_DIR NAMES "rustls.h")
52  find_library(RUSTLS_LIBRARY NAMES "rustls")
53
54  include(FindPackageHandleStandardArgs)
55  find_package_handle_standard_args(Rustls
56    REQUIRED_VARS
57      RUSTLS_INCLUDE_DIR
58      RUSTLS_LIBRARY
59  )
60
61  if(RUSTLS_FOUND)
62    set(RUSTLS_INCLUDE_DIRS ${RUSTLS_INCLUDE_DIR})
63    set(RUSTLS_LIBRARIES    ${RUSTLS_LIBRARY})
64  endif()
65
66  mark_as_advanced(RUSTLS_INCLUDE_DIR RUSTLS_LIBRARY)
67endif()
68
69if(APPLE)
70  find_library(SECURITY_FRAMEWORK "Security")
71  mark_as_advanced(SECURITY_FRAMEWORK)
72  if(NOT SECURITY_FRAMEWORK)
73    message(FATAL_ERROR "Security framework not found")
74  endif()
75  list(APPEND RUSTLS_LIBRARIES "-framework Security")
76
77  find_library(FOUNDATION_FRAMEWORK "Foundation")
78  mark_as_advanced(FOUNDATION_FRAMEWORK)
79  if(NOT FOUNDATION_FRAMEWORK)
80    message(FATAL_ERROR "Foundation framework not found")
81  endif()
82  list(APPEND RUSTLS_LIBRARIES "-framework Foundation")
83elseif(NOT WIN32)
84  find_library(_pthread_library "pthread")
85  if(_pthread_library)
86    list(APPEND RUSTLS_LIBRARIES "pthread")
87  endif()
88  mark_as_advanced(_pthread_library)
89
90  find_library(_dl_library "dl")
91  if(_dl_library)
92    list(APPEND RUSTLS_LIBRARIES "dl")
93  endif()
94  mark_as_advanced(_dl_library)
95
96  find_library(_math_library "m")
97  if(_math_library)
98    list(APPEND RUSTLS_LIBRARIES "m")
99  endif()
100  mark_as_advanced(_math_library)
101endif()
102