xref: /curl/CMake/FindLibpsl.cmake (revision f66af623) 
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the libpsl library
25#
26# Input variables:
27#
28# - `LIBPSL_INCLUDE_DIR`:   The libpsl include directory.
29# - `LIBPSL_LIBRARY`:       Path to `libpsl` library.
30#
31# Result variables:
32#
33# - `LIBPSL_FOUND`:         System has libpsl.
34# - `LIBPSL_INCLUDE_DIRS`:  The libpsl include directories.
35# - `LIBPSL_LIBRARIES`:     The libpsl library names.
36# - `LIBPSL_VERSION`:       Version of libpsl.
37
38if(CURL_USE_PKGCONFIG)
39  find_package(PkgConfig QUIET)
40  pkg_check_modules(PC_LIBPSL "libpsl")
41endif()
42
43find_path(LIBPSL_INCLUDE_DIR NAMES "libpsl.h"
44  HINTS
45    ${PC_LIBPSL_INCLUDEDIR}
46    ${PC_LIBPSL_INCLUDE_DIRS}
47)
48
49find_library(LIBPSL_LIBRARY NAMES "psl" "libpsl"
50  HINTS
51    ${PC_LIBPSL_LIBDIR}
52    ${PC_LIBPSL_LIBRARY_DIRS}
53)
54
55if(PC_LIBPSL_VERSION)
56  set(LIBPSL_VERSION ${PC_LIBPSL_VERSION})
57elseif(LIBPSL_INCLUDE_DIR AND EXISTS "${LIBPSL_INCLUDE_DIR}/libpsl.h")
58  set(_version_regex "#[\t ]*define[\t ]+PSL_VERSION[\t ]+\"([^\"]*)\"")
59  file(STRINGS "${LIBPSL_INCLUDE_DIR}/libpsl.h" _version_str REGEX "${_version_regex}")
60  string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
61  set(LIBPSL_VERSION "${_version_str}")
62  unset(_version_regex)
63  unset(_version_str)
64endif()
65
66include(FindPackageHandleStandardArgs)
67find_package_handle_standard_args(Libpsl
68  REQUIRED_VARS
69    LIBPSL_INCLUDE_DIR
70    LIBPSL_LIBRARY
71  VERSION_VAR
72    LIBPSL_VERSION
73)
74
75if(LIBPSL_FOUND)
76  set(LIBPSL_INCLUDE_DIRS ${LIBPSL_INCLUDE_DIR})
77  set(LIBPSL_LIBRARIES    ${LIBPSL_LIBRARY})
78endif()
79
80mark_as_advanced(LIBPSL_INCLUDE_DIR LIBPSL_LIBRARY)
81